{ inputs, ... }:
{
  perSystem =
    { pkgs, ... }:
    let
      npins' = pkgs.npins.overrideAttrs (
        final: old: {
          src = pkgs.fetchFromGitHub {
            owner = "javalsai";
            repo = "npins";
            rev = "f3def7dfeecc16884cb0601f6c904d5142f47383";
            hash = "sha256-ejeOGmDw+D4KddFJ5OAPradqoS+p2eAhhS4fOLQOWOk=";
          };

          cargoHash = null;
          cargoDeps = pkgs.rustPlatform.fetchCargoVendor {
            src = final.src;
            hash = "sha256-mG4UClFBgiWBraWQ12N3CSyapaIpuXI9F8wQGwh/ooQ=";
          };

          cargoBuildFeatures = [ ];
        }
      );
    in
    {
      devShells.default = pkgs.mkShell {
        name = "configuration.nix";

        shellHook = ''
          for path in \
            /usr/lib/qemu/qemu-bridge-helper \
            /run/wrappers/bin/qemu-bridge-helper
          do
            if [ -x "$path" ]; then
              export QEMU_BRIDGE_HELPER_PATH="$path"
              break
            fi
          done

          if [ -z "$QEMU_BRIDGE_HELPER_PATH" ]; then
            printf "\033[1;33m%s\033[0m\n" \
              "WARN: 'qemu-bridge-helper' not found, make sure it is installed and the nix shell hook is looking for it" >&2
          fi
        '';

        packages = with pkgs; [
          bat
          cachix
          deadnix
          delta
          git
          inputs.agenix.packages.${stdenv.hostPlatform.system}.default
          jujutsu
          nix-output-monitor
          nixfmt
          npins'
          parted
          smartmontools
          statix
          tmux
        ];
      };
    };
}