docs(nix module): add

howtf did it work in my VM, oh nvm

.github/workflows/make-release.yml

@@ -16,17 +16,33 @@ jobs:
           packages: "git"
           version: 1.0
       - uses: actions/checkout@v4
+        with:
+          fetch-tags: true
 
       - name: Check Version Changed
         id: check-ver-changed
         run: |
           GIT_TAG=$(git describe --no-long --abbrev=0 --tags --always)
+
           MAKE_TAG=$(make print-version)
+          NIX_VER=$(sed -nE \
+            's/.*version\s*=\s*"([0-9.]*)".*/\1/p' \
+            assets/pkg/nix/module.nix
+          )
 
           if [[ "$GIT_TAG" == "v$MAKE_TAG" ]]; then
             echo "ERR: Git tag matches makefile, did you bump Makefile up?" >&2
             exit 1
           fi
+          if [[ "$GIT_TAG" == "v$NIX_VER" ]]; then
+            echo "ERR: Nix module version matches git, did you bump Nix up?" >&2
+            exit 1
+          fi
+
+          if ! [[ "$NIX_VER" == "$MAKE_TAG" ]]; then
+            echo "ERR: Nix module version and make tag don't match" >&2
+            exit 1
+          fi
           echo "VERSION=$MAKE_TAG" >> "$GITHUB_OUTPUT"
 
 

INSTALL.md

@@ -4,6 +4,7 @@
 - [Installing from Source](#installing-from-source)
 - [AUR](#aur)
 - [Nix Flake](#nix-flake)
+- [Nix Module](#nix-module)
 
 > [!CAUTION]
 > I encourage you to read the manual installation steps to understand what will get installed in your computer by this package.
@@ -73,3 +74,54 @@ nix run github:javalsai/lidm
 
 > [!CAUTION]
 > This doesn't include [service files](./assets/pkg/aur#services) neither
+
+# Nix Module
+
+<details>
+<summary>Sidenote</summary>
+
+The nix module lacks on several aspects, if you know much about nix and know
+how to improve this package, feel free to open an issue or a PR to help. The
+nix package maintainer position is open too.
+
+</details>
+
+Lidm includes a nix module in `assets/pkg/nix/module.nix` that you can add
+(along the included nix files) and import in your `configuration.nix`.
+
+Once imported you'll need to add:
+
+```nix
+services.displayManager.enable = true;
+systemd.services.lidm.enable = true;
+```
+
+Optionally, you can configure it setting `services.lidm.config`. You can either
+pass:
+
+* A string to copy the config from a theme in `themes/` with said name
+  (**name**, e.g `"cherry"`).
+* An attribute tree with the same names as the config file, e.g:
+```nix
+{
+    strings = {
+        f_poweroff = "custom_poweroff";
+        # etc
+    };
+    behavior = {
+        include_defshell = true;
+        source = [
+            "path1"
+            "path2"
+        ];
+        # etc
+    };
+    # etc
+};
+```
+
+> *it's not necessary to cover all keys and anything can be put there, even if
+> its not valid config*
+
+> [!NOTE]
+> [service files](./assets/pkg/aur#services) **are** included and enabled

Makefile

@@ -10,7 +10,9 @@ PREFIX=/usr
 
 CC?=gcc
 CFLAGS?=-O3 -Wall
-ALLFLAGS=$(CFLAGS) -I$(IDIR)
+# C PreProcessor flags, not C Plus Plus
+CPPFLAGS?=
+ALLFLAGS=$(CFLAGS) $(CPPFLAGS) -I$(IDIR)
 
 LIBS=-lpam
 

aaaa/etc/sv/lidm/conf

@@ -1,5 +0,0 @@
-BAUD_RATE=38400
-TERM_NAME=linux
-
-TTY=tty7
-EXEC_PATH=/bin/lidm

aaaa/etc/sv/lidm/finish

@@ -1,5 +0,0 @@
-#!/bin/sh
-
-[ -r conf ] && . ./conf
-
-exec utmpset -w $TTY

aaaa/etc/sv/lidm/run

@@ -1,15 +0,0 @@
-#!/bin/sh
-
-[ -r conf ] && . ./conf
-
-if [ -x /sbin/getty -o -x /bin/getty ]; then
-	# busybox
-	GETTY=getty
-elif [ -x /sbin/agetty -o -x /bin/agetty ]; then
-	# util-linux
-	GETTY=agetty
-fi
-
-exec setsid ${GETTY} ${GETTY_ARGS} \
-	"${TTY}" "${TERM_NAME}" \
-	-n -l "${EXEC_PATH}" -o 7

assets/pkg/nix/get-cfg-file.nix

@@ -0,0 +1,13 @@
+{ cfg, src, lib, ... }:
+let
+    maker = import ./make-cfg.nix {
+        inherit lib;
+        keys-h-file = builtins.readFile "${src}/include/keys.h";
+    };
+in builtins.toFile "lidm.conf" (
+    if builtins.isString cfg
+        then builtins.readFile "${src}/themes/${cfg}.ini"
+    else if builtins.isAttrs cfg
+        then maker.make cfg
+    else builtins.throw "invalid cfg type, expected str or attrs"
+)

assets/pkg/nix/lidm.nix

@@ -0,0 +1,35 @@
+{ config, pkgs, lib, ...}:
+let
+    cfg-file = if config.cfg != null then
+        import ./get-cfg-file.nix {
+            inherit lib;
+            inherit (config) cfg src;
+        }
+    else null;
+in
+pkgs.stdenv.mkDerivation rec {
+    pname = "lidm";
+    version = config.version;
+    src = config.src;
+
+    nativeBuildInputs = with pkgs; [
+        gcc
+        gnumake
+        linux-pam
+    ];
+
+    makeFlags = [
+        "DESTDIR=$(out)"
+        "PREFIX="
+    ]
+    ++ lib.optional (config.xsessions != null)
+        "CPPFLAGS+=-DSESSIONS_XSESSIONS=\\\"${config.xsessions}\\\""
+    ++ lib.optional (config.wayland-sessions != null)
+        "CPPFLAGS+=-DSESSIONS_WAYLAND=\\\"${config.wayland-sessions}\\\""
+    ++ lib.optional (cfg-file != null)
+        "CPPFLAGS+=-DLIDM_CONF_PATH=\\\"${cfg-file}\\\"";
+
+    fixupPhase = ''
+        rm -rf $out/etc
+    '';
+}

assets/pkg/nix/make-cfg.nix

@@ -0,0 +1,70 @@
+{ lib, keys-h-file }:
+
+let
+    double-match-to-nameval = dmatch: { name = builtins.elemAt dmatch 0; value = builtins.elemAt dmatch 1; };
+
+    keys-enum = let
+        key-names = builtins.replaceStrings ["\n" " "] ["" ""] (
+            builtins.elemAt (
+                builtins.match
+                    ".*KEY_NAMES\\[][[:blank:]]*=[[:blank:]]*\\{([^}]*)}.*"
+                    keys-h-file
+            ) 0
+        );
+
+        keys-2d-list = builtins.map
+            (builtins.match "\\[(.*)]=\"(.*)\"")
+            (builtins.filter
+                (s: builtins.isString s && s != "")
+                (builtins.split "," key-names)
+            );
+
+    in builtins.listToAttrs (
+        builtins.map
+            (k: k // { value = { __enum_key = k.value; }; })
+            (builtins.map double-match-to-nameval keys-2d-list)
+    );
+in {
+    inherit keys-enum;
+    make = let
+        name-val-to-attrs = (name: value: { inherit name value; } );
+        map-attrs = attrset: fn: lib.map fn
+            (lib.attrsets.mapAttrsToList name-val-to-attrs attrset);
+
+        try-foldl' = op: nul: list:
+            if (builtins.length list) == 0 then ""
+            else builtins.foldl' op nul list;
+        concat-with = sepr: list: try-foldl'
+            (x: y: if x == null then y else x + sepr + y)
+            null
+            list;
+
+        ser-bool = bool: if bool then "true" else "false";
+        ser-str = str: "\"${builtins.replaceStrings ["\n" "\""] ["\\n" "\\\""] str}\"";
+        ser-kvs = { name, value }: if builtins.isList value then
+            concat-with "\n" (
+                builtins.map
+                    (value: ser-kvs { inherit name value; })
+                    value
+            )
+        else "${name} = ${
+            if builtins.isString value then
+                ser-str value
+            else if builtins.isInt value then
+                builtins.toString value
+            else if builtins.isBool value then
+                ser-bool value
+            else if builtins.isAttrs value then
+                value.__enum_key
+            else builtins.throw "type not supported"
+        }";
+
+        ser-table = table': let
+            tname = table'.name;
+            table = table'.value;
+        in
+        "[${tname}]\n" + (
+            concat-with "\n" (map-attrs table ser-kvs)
+        );
+    in cfg: concat-with "\n\n" (map-attrs cfg ser-table);
+}

assets/pkg/nix/module.nix

@@ -0,0 +1,55 @@
+{ config, lib, pkgs, ... }:
+
+let
+    cfg = config.services.lidm;
+
+    dmcfg = config.services.displayManager;
+    desktops = dmcfg.sessionData.desktops;
+
+    version = "1.2.1";
+    lidmPkg = pkgs.callPackage ./lidm.nix {
+        inherit pkgs;
+        config = {
+            inherit version lib;
+            cfg = cfg.config;
+            src = pkgs.fetchFromGitHub {
+              owner = "javalsai";
+              repo = "lidm";
+              rev = "v${version}";
+              sha256 = "sha256-3CgUI8PUs4c1bfBrykPw87SSa4lzrh4E4Hug7cGRKFk=";
+            };
+
+            xsessions = "${desktops}/share/xsessions";
+            wayland-sessions = "${desktops}/share/wayland-sessions";
+        };
+    };
+in
+{
+    options.services.lidm.config = lib.mkOption {
+        type = with lib.types; oneOf [ str attrs ];
+        default = {};
+        description = "Config options for lidm | Either attr tree or name of bundled themes";
+    };
+    config = {
+        services.displayManager.defaultSession = "lidm";
+
+        systemd.services.lidm = {
+            description = "TUI display manager";
+            aliases = [ "display-manager.service" ];
+            after = [
+                "systemd-user-sessions.service"
+                "plymouth-quit-wait.service"
+            ];
+            serviceConfig = {
+                Type = "idle";
+                ExecStart = "${lidmPkg}/bin/lidm 7";
+                StandardInput = "tty";
+                StandardOutput = "tty";
+                StandardError = "tty";
+                TTYPath = "/dev/tty7";
+                TTYReset = "yes";
+                TTYVHangup = "yes";
+            };
+        };
+    };
+}

assets/services/systemd.service

@@ -5,9 +5,9 @@ After=systemd-user-sessions.service plymouth-quit-wait.service
 [Service]
 Type=idle
 ExecStart=/usr/bin/lidm 7
-StandardError=journal
 StandardInput=tty
 StandardOutput=tty
+StandardError=tty
 TTYPath=/dev/tty7
 TTYReset=yes
 TTYVHangup=yes

flake.nix

@@ -1,8 +1,11 @@
 {
+  description = "A ✨fully✨ colorful customizable TUI display manager made in C for simplicity.";
+
   inputs = {
     flake-utils.url = "github:numtide/flake-utils";
     nixpkgs.url = "github:nixos/nixpkgs?ref=nixos-unstable";
   };
+
   outputs =
     { flake-utils, nixpkgs, ... }:
     flake-utils.lib.eachDefaultSystem (
@@ -11,36 +14,29 @@
         pkgs = import nixpkgs { inherit system; };
 
         name = "lidm";
-        version = "0.0.2";
-
-        lidm = (
-          pkgs.stdenv.mkDerivation {
-            pname = name;
-            version = version;
+        version = builtins.elemAt (
+          builtins.match "VERSION[[:blank:]]*=[[:space:]]*([^\n]*)\n.*" (builtins.readFile ./Makefile)
+        ) 0;
 
+        lidm = pkgs.callPackage assets/pkg/nix/lidm.nix {
+          inherit pkgs;
+          lib = pkgs.lib;
+          config = {
+            inherit version;
             src = ./.;
-
-            nativeBuildInputs = with pkgs; [
-              gcc
-              gnumake
-              linux-pam
-            ];
-
-            makeFlags = [
-              "DESTDIR=$(out)"
-              "PREFIX="
-            ];
-
-            fixupPhase = ''
-              rm -rf $out/etc
-            '';
-          }
-        );
+            xsessions = null;
+            wayland-sessions = null;
+            cfg = null;
+            # cfg = "cherry";
+          };
+        };
       in
       rec {
         defaultApp = flake-utils.lib.mkApp { drv = defaultPackage; };
         defaultPackage = lidm;
         devShell = pkgs.mkShell { buildInputs = lidm.nativeBuildInputs ++ [ pkgs.clang-tools ]; };
       }
-    );
+    ) // {
+      nixosModules.lidm = assets/pkg/nix/module.nix;
+    };
 }

include/macros.h

@@ -1,6 +1,11 @@
 #ifndef MACROSH_
 #define MACROSH_
 
+// More like constants but I'm not making yet another header file just for this
+#ifndef LIDM_CONF_PATH
+  #define LIDM_CONF_PATH "/etc/lidm.ini"
+#endif
+
 // Do we just replace the compiler with clang??
 #if defined(__clang__)
   #define NULLABLE _Nullable

src/config.c

@@ -12,6 +12,7 @@
 #include "config.h"
 #include "desktop.h"
 #include "log.h"
+#include "macros.h"
 #include "util.h"
 
 #define UPPER_HALF_BYTE 4
@@ -240,12 +241,10 @@ struct status config_line_handler(void* _config, char* table, char* k,
 int parse_config(struct config* NNULLABLE config, char* NNULLABLE path) {
   FILE* fd = fopen(path, "r");
   if (fd == NULL) {
-    perror("fopen");
-    (void)fputs(
-        "Please place a config file at /etc/lidm.ini or set the LIDM_CONF "
-        "env variable",
-        stderr);
-    return -1;
+    log_perror("fopen");
+    log_printf(" [I] No config, place one at " LIDM_CONF_PATH
+               " or set the LIDM_CONF env variable");
+    return 0; // Its fine now anyways
   }
 
   bool ret = read_desktop(fd, config, config_line_handler);

src/desktop.c

@@ -66,7 +66,8 @@ int read_desktop(FILE* fd, void* ctx,
       buf_start[eq_idx] = '\0'; // the equal
       key = trim_str(key);
       char* value = &buf_start[eq_idx + 1];
-      buf_start[read_size - 1] = '\0'; // the newline
+      if(buf_start[read_size - 1] == '\n')
+        buf_start[read_size - 1] = '\0';
       value = trim_str(value);
 
       // Callback

src/main.c

@@ -72,9 +72,10 @@ int main(int argc, char* argv[]) {
     chvt_str(argv[1]);
   }
 
+  // Copy
   struct config config = DEFAULT_CONFIG;
   char* conf_override = getenv("LIDM_CONF");
-  char* conf_path = conf_override ? conf_override : "/etc/lidm.ini";
+  char* conf_path = conf_override ? conf_override : LIDM_CONF_PATH;
   if (parse_config(&config, conf_path) != 0) {
     (void)fputs("error parsing config\n", stderr);
     return 1;

src/sessions.c

@@ -16,9 +16,16 @@ struct source_dir {
   enum session_type type;
   char* dir;
 };
+
+#ifndef SESSIONS_XSESSIONS
+  #define SESSIONS_XSESSIONS "/usr/share/xsessions"
+#endif
+#ifndef SESSIONS_WAYLAND
+  #define SESSIONS_WAYLAND "/usr/share/wayland-sessions"
+#endif
 static const struct source_dir SOURCES[] = {
-    {XORG, "/usr/share/xsessions"},
-    {WAYLAND, "/usr/share/wayland-sessions"},
+    {XORG, SESSIONS_XSESSIONS},
+    {WAYLAND, SESSIONS_WAYLAND},
 };
 
 static struct Vector* cb_sessions = NULL;